Forum

import QtQuick 2.12
import QtMultimedia 5.8
import org.kde.plasma.networkmanagement 0.2 as PlasmaNM
import org.kde.plasma.plasmoid 2.0

Item {
id: root
property string artist
property string artisturl
property string song
property string songurl
property string title: Plasmoid.title
property bool isError: false
property string tooltipimage
property string albumimage
property string album
property string albumurl
property int lastPlay: -1
property bool isConnected: networkStatus.networkStatus === i18nd(
"plasma_applet_org.kde.plasma.networkmanagement",
"Connected")
Plasmoid.preferredRepresentation: Plasmoid.compactRepresentation
StationsModel {
id: stationsModel
}
Component.onCompleted: {
reloadStationsModel()
}
Connections {
target: plasmoid.configuration
function onServersChanged() {
playMusic.stop()
reloadStationsModel()
}
}

MediaPlayer {
id: playMusic
property string title: isPlaying()
&& playMusic.metaData.title ? playMusic.metaData.title : null
onTitleChanged: {
if (isPlaying()) {
getInfo(playMusic.metaData.title)
}
}
onError: {
isError = true
errorTimer.start()
}
onStopped: {
playMusic.stop()
playMusic.source = ""
root.title = Plasmoid.title
root.albumimage = ""
root.tooltipimage = ""
root.album = ""
root.albumurl = ""
root.artist = ""
root.artisturl = ""
root.song = ""
root.songurl = ""
}
volume: 0.75
}

Timer {
id: errorTimer
running: false
repeat: false
interval: 5000
onTriggered: {
isError = false
}
}

Plasmoid.compactRepresentation: CompactRepresentation {}

Plasmoid.fullRepresentation: FullRepresentation {
id: dialogItem
anchors.fill: parent
focus: true
}
function isPlaying() {
return playMusic.playbackState === MediaPlayer.PlayingState
}
function reloadStationsModel() {
playMusic.stop()
stationsModel.clear()
try {
var servers = JSON.parse(plasmoid.configuration.servers)
for (var i = 0; i < servers.length; i++) {
if (servers[i].active) {
stationsModel.append(servers[i])
}
}
} catch (e) {
console.log(e)
}
}

PlasmaNM.NetworkStatus {
id: networkStatus
onNetworkStatusChanged: {
if (networkStatus.networkStatus === i18nd(
"plasma_applet_org.kde.plasma.networkmanagement",
"Connected")) {
root.isConnected = true
} else {
console.log("Connection lost")
root.isConnected = false
}
}
}
function getInfo(data) {
if (data !== undefined && data.indexOf('-') !== -1) {
var strings // Magic to check non-standard artists/songs like "A-ha - Minor earth major sky"
if (data.indexOf(' - ') !== -1) {
strings = data.split(' - ')
} else {
strings = data.split('-')
}
var artist = strings[0].trim(), song = strings[1].trim()
var xmlhttp = new XMLHttpRequest()
var url = "http://ws.audioscrobbler.com/2.0/?method=track.getInfo&api_key=ada39a6834a3be4d641cc1aec7e64d48&artist=" + encodeURIComponent(
artist) + "&track=" + encodeURIComponent(
song) + "&autocorrect=1&format=json"
xmlhttp.onreadystatechange = function () {
if (xmlhttp.readyState == 4 && xmlhttp.status == 200) {
setInfo(JSON.parse(xmlhttp.responseText))
}
}
xmlhttp.open("GET", url)
xmlhttp.send()
function setInfo(arr) {
root.artist = (arr.track
&& arr.track.artist) ? (arr.track.artist.name) : artist
root.song = (arr.track) ? (arr.track.name) : song
root.title = (isPlaying(
)) ? root.artist + " - " + root.song : Plasmoid.title
root.artisturl = (arr.track
&& arr.track.artist) ? (arr.track.artist.url) : ""
root.songurl = (arr.track
&& arr.track.url) ? (arr.track.url) : ""

root.albumimage = arr.track && arr.track.album
&& arr.track.album.image[1]['#text'] ? arr.track.album.image[1]['#text'] : ""
root.tooltipimage = arr.track && arr.track.album
&& arr.track.album.image[0]['#text'] ? arr.track.album.image[0]['#text'] : ""
root.album = arr.track && arr.track.album
&& arr.track.album.title
&& arr.track.album.title != "" ? arr.track.album.title : ""
root.albumurl = arr.track && arr.track.album
&& arr.track.album.url
&& arr.track.album.url != "" ? arr.track.album.url : ""
}
} else {
root.title = isPlaying() && playMusic.metaData.title
&& !playMusic.metaData.title.startsWith(
"{") ? playMusic.metaData.title : Plasmoid.title // "{" fix for some stations
}
}
}

import QtQuick 2.12
import QtQuick.Layouts 1.0
import org.kde.plasma.core 2.0 as PlasmaCore
import org.kde.plasma.extras 2.0 as PlasmaExtras
import org.kde.plasma.components 3.0 as PlasmaComponents3
import org.kde.plasma.plasmoid 2.0

PlasmaExtras.Representation {
id: fullRepresentation
Layout.minimumWidth: PlasmaCore.Units.gridUnit * 14
Layout.minimumHeight: PlasmaCore.Units.gridUnit * 18
Layout.maximumWidth: PlasmaCore.Units.gridUnit * 56
Layout.maximumHeight: PlasmaCore.Units.gridUnit * 36
collapseMarginsHint: true
readonly property var appletInterface: Plasmoid.self
header: PlasmaExtras.PlasmoidHeading {
id: header
focus: true
visible: true
RowLayout {
spacing: 0
Rectangle {
Layout.fillWidth: true
implicitWidth: fullRepresentation.width
width: fullRepresentation.width
implicitHeight: heading.height
Layout.topMargin: PlasmaCore.Units.smallSpacing
Layout.bottomMargin: PlasmaCore.Units.smallSpacing
color: "transparent"
clip: true
onWidthChanged: {
if (isPlaying()) {
header.calculateAnimation()
} else {
anim.stop()
heading.x = -heading.width / 2 + fullRepresentation.width / 2
}
}

PlasmaExtras.Heading {
id: heading
maximumLineCount: 1
anchors.verticalCenter: parent.verticalCenter
text: root.title
level: 1
onTextChanged: {
if (isPlaying()) {
header.calculateAnimation()
} else {
anim.stop()
heading.x = -heading.width / 2 + fullRepresentation.width / 2
}
}
}
}

XAnimator {
id: anim
target: heading
easing.type: Easing.Linear
duration: Math.round(
Math.abs(to - from) / PlasmaCore.Units.gridUnit
* (PlasmaCore.Units.longDuration + PlasmaCore.Units.shortDuration))
}
}
function calculateAnimation() {
anim.from = width + PlasmaCore.Units.gridUnit
anim.to = -heading.width
anim.loops = Animation.Infinite
anim.restart()
}
}

PlasmaComponents3.ScrollView {
id: scrollView
anchors.fill: parent
PlasmaComponents3.ScrollBar.horizontal.policy: PlasmaComponents3.ScrollBar.AlwaysOff
contentWidth: availableWidth - contentItem.leftMargin - contentItem.rightMargin
contentItem: ListView {
id: stationView
leftMargin: PlasmaCore.Units.smallSpacing
rightMargin: PlasmaCore.Units.smallSpacing
topMargin: PlasmaCore.Units.smallSpacing
bottomMargin: PlasmaCore.Units.smallSpacing
model: stationsModel
enabled: isConnected
focus: true
currentIndex: -1
boundsBehavior: Flickable.StopAtBounds
clip: true
delegate: MediaListItem {}
Connections {
target: playMusic
function onError() {
stationView.currentIndex = -1
}
}
}
}
footer: PlasmaExtras.PlasmoidHeading {
RowLayout {
Rectangle {
implicitWidth: fullRepresentation.width
width: fullRepresentation.width
Layout.preferredHeight: childrenRect.height
Layout.topMargin: PlasmaCore.Units.smallSpacing
Layout.bottomMargin: PlasmaCore.Units.smallSpacing
color: "transparent"
PlasmaComponents3.Label {
id: subtext
font: PlasmaCore.Theme.smallestFont
width: parent.width
clip: true
color: isError
|| !isConnected ? PlasmaCore.ColorScope.negativeTextColor : PlasmaCore.ColorScope.textColor
text: !isConnected ? i18n("Check internet connection...") : root.isError ? i18n("Error: ") + playMusic.errorString : isPlaying() && playMusic.status == 6 ? i18n("Bitrate: ") + Math.round(playMusic.metaData.audioBitRate / 1000) + 'Kb/s, ' + i18n("Genre: ") + playMusic.metaData.genre : playMusic.bufferProgress < 1 && playMusic.status != 1 ? i18n("Buffering...") + ' ' + Math.round(playMusic.bufferProgress * 100) + "%" : i18n("Choose station and enjoy...")
anchors.verticalCenter: parent.verticalCenter
horizontalAlignment: Text.AlignHCenter
elide: Text.ElideRight
}
}
}
}
}